C***********************************************************************
C***
C*** MODELLO PER LO STUDIO DI MACCHINA A RISONANZA A FLESSIONE ROTANTE
C*** PER DRILL PIPES IN PIENA SCALA
C***

finish
/clear
/triad,off

/title,vibrazione forzata
/filname,vibrazione_forzata

/prep7

pi = acos(-1)

c*** 	DATI DEL MODELLO
m_box = 101 ! massa fissa estremo sx box [kg]
m_pin_fix = 103 ! massa fissa estremo dx pin [kg]
Me = 5.8   ! massa eccentrica [kg]
e = 0.0557 ! eccentricità [m]
smorz = 0.001 !Smorzamento percentuale
m_pin = m_pin_fix+Me
f_max=40	! frequenza max
pfrq=1		! passo di frequenza

C***		Dati tubo

! diameters and lenghts [m]

L_box = 2.030 ! box cut lenght [m]
L_pin = 1.900 ! pin cut lenght [m]

L2 = 0.103 ! box upset transition [m]
DO_2 = (0.1492+0.1524)/2
DI_2 = (0.12812+0.1143)/2

L3 = 0.1154 ! box upset [m]
DO_3 = 0.1524
DI_3 = 0.1143

L4 = 0.04326 ! ext. upset transition [m]
DO_4 = (0.1778+0.1524)/2
DI_4 = 0.1143

L5 = 0.6604 ! connection [m]
DO_5 = 0.1778
DI_5 = 0.1143


L6 = 0.03015 ! mixed material length [m]
DO_6 = DO_4
DI_6 = DI_4

L7 = L3 ! pin upset length [m]
DO_7 = DO_3
DI_7 = DI_3

L8 = L2 ! pin upset transition length [m]
DO_8 = DO_2
DI_8 = DI_2

L1 = L_box-(L2+L3+L4)-0.3556 ! initial box length [m]
DO_1 = 0.1492
DI_1 = 0.12812

L9 = L_pin-(L6+L7+L8)-0.3048 ! final pin length [m]
DO_9 = DO_1
DI_9 = DI_1

LT = L1+L2+L3+L4+L5+L6+L7+L8+L9

! material properties
s_dens = 7800 ! steel density [kg/m^3]
s_E = 205E+9 ! steel Young's modulus [Pa]
s_pr = 0.3 ! steel Poisson ratio

mp,dens,1,s_dens
mp,ex,1,s_E
mp,prxy,1,s_pr



! elemento tipo trave valido per tutti i tratti
ET,1,188,,,3	! FUNZIONE DI FORMA DI GRADO 3

! elementi massa concentrata
et,2,21,,,2

! real constants
SECTYPE,1,BEAM,CTUBE,TUBO1
SECDATA,DI_1/2,DO_1/2

SECTYPE,2,BEAM,CTUBE,TUBO2
SECDATA,DI_2/2,DO_2/2

SECTYPE,3,BEAM,CTUBE,TUBO3
SECDATA,DI_3/2,DO_3/2

SECTYPE,4,BEAM,CTUBE,TUBO4
SECDATA,DI_4/2,DO_4/2

SECTYPE,5,BEAM,CTUBE,TUBO5
SECDATA,DI_5/2,DO_5/2

SECTYPE,6,BEAM,CTUBE,TUBO6
SECDATA,DI_6/2,DO_6/2

SECTYPE,7,BEAM,CTUBE,TUBO7
SECDATA,DI_7/2,DO_7/2

SECTYPE,8,BEAM,CTUBE,TUBO8
SECDATA,DI_8/2,DO_8/2

SECTYPE,9,BEAM,CTUBE,TUBO9
SECDATA,DI_9/2,DO_9/2

A_9 = pi/4*(DO_9**2-DI_9**2)
Iyy_9 = pi/64*(DO_9**4-DI_9**4)
Izz_9 = pi/64*(DO_9**4-DI_9**4)
r,9,A_9,Iyy_9,Izz_9,DO_9,DO_9,
rmore,,Iyy_9+Izz_9


! fixed mass box side
r,10,m_box

! fixed mass pin side
r,11,m_pin

C***
C***	modello
C***

k,1
k,2,L1
k,3,L1+L2
k,4,L1+L2+L3
k,5,L1+L2+L3+L4
k,6,L1+L2+L3+L4+L5
k,7,L1+L2+L3+L4+L5+L6
k,8,L1+L2+L3+L4+L5+L6+L7
k,9,L1+L2+L3+L4+L5+L6+L7+L8
k,10,L1+L2+L3+L4+L5+L6+L7+L8+L9
k,11,L1+L2+L3+L4,L1

l,1,2
l,2,3
l,3,4
l,4,5
l,5,6
l,6,7
l,7,8
l,8,9
l,9,10

ndivs = 10

lesize,all,,,ndivs
lesize,1,,,2*ndivs
lesize,5,,,2*ndivs
lesize,9,,,2*ndivs

! beam elements
LSEL,,LINE,,1
LATT,1,,1,,11,11,1
LSEL,ALL

LSEL,,LINE,,2
LATT,1,,1,,11,11,2
LSEL,ALL

LSEL,,LINE,,3
LATT,1,,1,,11,11,3
LSEL,ALL

LSEL,,LINE,,4
LATT,1,,1,,11,11,4
LSEL,ALL

LSEL,,LINE,,5
LATT,1,,1,,11,11,5
LSEL,ALL

LSEL,,LINE,,6
LATT,1,,1,,11,11,6
LSEL,ALL

LSEL,,LINE,,7
LATT,1,,1,,11,11,7
LSEL,ALL

LSEL,,LINE,,8
LATT,1,,1,,11,11,8
LSEL,ALL

LSEL,,LINE,,9
LATT,1,,1,,11,11,9
LSEL,ALL

LMESH,ALL

! fixed masses
type,2
real,10
nsel,s,loc,x,-0.001,0.001
*get,nodemass,node,,num,max
e,nodemass
alls

real,11
nsel,s,loc,x,LT-0.001,LT+0.001
*get,nodemass,node,,num,max
e,nodemass
alls

finish


! analisi armonica
/solu

antype,harmic            
hropt,full		  

dmprat,smorz
NSTP=NINT(f_max/pfrq + 0.5)


*do,i,1,NSTP
frequenza = f_max/NSTP*i

harfrq,frequenza
hrout,off	  

!  applicazione della forza rotante
nsel,s,loc,x,LT-0.001,LT+0.001
*get,nodemass,node,,num,max
f,nodemass,fy,Me*e*((2*pi*frequenza)**2)
f,nodemass,fz,,Me*e*((2*pi*frequenza)**2)
alls

lswrite,i

*enddo

lssolve,1,NSTP

C*** POST-PROCESSING
C***
/POST26

N1=NODE(L1+L2+L3,0,0)	! ricerca il numero dei nodo del provino siti nella zone critiche
N2=NODE(L1+L2+L3+L4+L5+L6,0,0)

NSEL,,NODE,,N1,N1	! seleziona il nodo centrale
ESLN			! seleziona gli elementi attaccati al nodo
*GET,E1,ELEM,0,NUM,MAX	! ricerca il numero di uno dei due
ALLS
ESOL,2,E1,N1,SMISC,34,SMAX1	! definisce la variabile (tensione max) da plottare

NSEL,,NODE,,N2,N2	! seleziona il nodo centrale
ESLN			! seleziona gli elementi attaccati al nodo
*GET,E2,ELEM,0,NUM,MAX	! ricerca il numero di uno dei due
ALLS

ESOL,3,E2,N2,SMISC,34,SMAX2	! definisce la variabile (tensione max) da plottare

STORE

PLVAR,2,3
*ASK,FRQ,RETURN PER CONTINUARE :,0


/post1
VMX=0
*DO,I,1,NSTP
!	/GOPR
	SET,I
	NSORT,U,SUM
	*GET,VMXC,SORT,0,MAX
	*IF,VMXC,GT,VMX,THEN
		VMX=VMXC
		NLST=I
	*ENDIF
*ENDDO
SET,NLST
/VIEW,,1,1,1
PLNSOL,U,SUM
ANHARM,100,0